Skip to main content

Notifications

Announcements

🌸 Community Spring Festival 2025 Challenge 🌸
News and Announcements icon
Community site session details

Community site session details

Session Id :
Dynamics 365 Community / Blogs / MS Dynamics 365FO Technical blogs / Project Hour Journal Creati...

Project Hour Journal Creation and Invoice Posting using x++ code

Vijay Yelmame VY Profile Picture Vijay Yelmame VY 468

Project Hour Journal Creation, posting , Invoice proposal creation and Posting invoice

Step-by-Step Guide

1. Creating the Project Hour Journal

The first step is to create a project hour journal. This involves initializing the journal table and transaction data, setting various properties, and validating the entries before inserting them into the database.

public journalId createJournal()
{
   
    ProjJournalTable jourTable;
    ProjJournalTableData jourTableData;
    ProjJournalTransData jourTransData;
    ProjJournalStatic jourStatic;
    ProjTable projtable;
    Qty qty;
    ProjLinePropertySetup projLinePropertySetup;
    TestSFIntegrationParameters TestSFIntegrationParameters = TestSFIntegrationParameters::find(); // Custom table.
    ProjLineProperty projLineProperty;
    ProjJournalTrans jourTrans;
    Amount totalAmount;
    JournalId journalId;

  
    select firstonly reverse projLinePropertySetup
        join projLineProperty
            where projLineProperty.LinePropertyId == projLinePropertySetup.LinePropertyId
            && projLinePropertySetup.CategoryRelation == TestSFIntegrationParameters.RevenueCategory
            && projLinePropertySetup.ProjCode == TableGroupAll::All;

    if (!projLineProperty.ToBeInvoiced)
    {
        throw error(strFmt("The chargeable line property is missing for the specified hour category '%1'.", TestSFIntegrationParameters.RevenueCategory));
    }

    jourTableData = JournalTableData::newTable(jourTable);
    jourTable.JournalId = jourTableData.nextJournalId();
    jourTable.JournalType = ProjJournalType::Hour;
    jourTable.JournalNameId = TestSFIntegrationParameters.RevenueJournalNameId;
    jourTableData.initFromJournalName(ProjJournalName::find(jourTable.JournalNameId));
    jourTable.Description = "Header description";
    jourStatic = jourTableData.journalStatic();

    if (jourtable.validatewrite())
    {
        jourtable.insert();
    }
    else
    {
        throw error("Validation failed to create journal header");
    }

    // Create journal transactions
    if (jourtable)
    {
        jourTransData = jourStatic.newJournalTransData(jourTrans, jourTableData);
        projtable = Projtable::find("ProjId0001");

        jourTrans.clear();
        jourTransData.initFromJournalTable();
        jourTrans.initValue();
        jourTrans.ProjId = projtable.ProjId;
        jourTrans.initFromProjTable(projtable);
        jourTrans.TransDate = DateTimeUtil::getSystemDate(DateTimeUtil::getUserPreferredTimeZone());
        jourTrans.ProjTransDate = jourTrans.TransDate;
        jourTrans.SalesPrice = 20.0;
        jourTrans.Txt = "Line description";
        jourTrans.Qty = 200;
        jourTrans.CurrencyId = 'CAN';
        jourTrans.CategoryId = TestSFIntegrationParameters.RevenueCategory;
        jourTrans.LinePropertyId = projLinePropertySetup.LinePropertyId;
        jourTrans.TaxItemGroupId = TestSFIntegrationParameters.TaxItemGroupId;

        if (jourTrans.validateWrite())
        {
            jourTransData.create(false);
            qty += jourTrans.Qty;
        }
        else
        {
            throw error("@ENG_Labels:ValidationFailedToCreateJournalLines");
        }

        jourTable.NumOfLines = real2int(jourTrans.LineNum);
        jourTable.ProjQty = qty;
        jourTable.doUpdate();
    }
    return jourTable.JournalId;
}
2. Posting Hour Journal

Once the journal is created, the next step is to post it. This ensures that the journal entries are finalized and recorded in the system.

public void postJournal(JournalId _journalId)
{
    ProjJournalCheckPost jourPost;
    jourPost = ProjJournalCheckPost::newJournalCheckPost(true, true, JournalCheckPostType::Post, tableNum(ProjJournalTable), _journalId);
    jourPost.runOperation();
}
3. Generating the Invoice Proposal

After posting the journal, we generate an invoice proposal based on the journal entries. This involves selecting the appropriate funding source and creating the proposal data.

public ProjProposalId invoiceProposalCreation(JournalId _journalId)
{
    ProjJournalTrans projJournalTrans;
    ProjTable projTable, parentprojTable;
    ProjFundingSourceRefId fundingSource;
    ProjFundingSource ProjFundingSource;
    ProjProposalId proposalId;

    select firstonly ParentId, defaultfundingsource, ProjInvoiceProjId from projTable
        join ProjId from projJournalTrans
            where projTable.ProjId == projJournalTrans.ProjId
               && ProjJournalTrans.JournalId == _journalId
               && ProjJournalTrans.LineNum == 1;

    select firstonly ProjInvoiceProjId, ProjGroupId, defaultfundingsource from parentprojTable
        where parentprojTable.ProjId == projTable.ParentId;

    fundingSource = projTable.DefaultFundingSource != 0 ? projTable.DefaultFundingSource : parentprojTable.DefaultFundingSource;

    if (!fundingSource)
    {
        select firstonly projFundingSource
            where projFundingSource.ContractId == projTable.ProjInvoiceProjId
            && projFundingSource.CustAccount == projTable.CustAccount
            && projFundingSource.FundingType == ProjFundingType::Customer;

        if (!projFundingSource)
        {
            throw error("Couldn't find funding source (Invoice account) for given parent and child project and on assigned contract.");
        }
        fundingSource = projFundingSource.RecId;
    }

    proposalId = TestCreateInvoiceProposal::createDataInTmp(fundingSource, _journalId);
    return proposalId;
}
4. Posting the Invoice Proposal

Finally, we post the invoice proposal to generate the actual invoice. This involves updating the proposal journal and running the form letter operation.

public InvoiceId postInvoiceProposal(ProjProposalId _proposalId)
{
    ProjProposalJour projProposalJour;
    ProjFormLetter projFormLetter;

    select forupdate projProposalJour order by RecId desc
        where projProposalJour.ProposalId == _proposalId;

    projProposalJour.PSAInvoiceTxtPre = "Invoice header text";
    projProposalJour.LineProperty = ProjLinePropertyCode::Approved;
    projProposalJour.editInvReportFormat(true, "PSAProjInvoice.Report");
    projProposalJour.update();

    projFormLetter = ProjFormLetter::construct(DocumentStatus::ProjectInvoice);
    projFormLetter.createParmLine(projProposalJour);
    projFormLetter.runOperation();

    projProposalJour = projProposalJour::find(projProposalJour.ProposalId);
    return projProposalJour.ProjInvoiceId;
}
Additional Class: TestCreateInvoiceProposal

Below is the additional class code for creating invoice proposals:

class TestCreateInvoiceProposal extends projInvoiceProposalInsertLines
{

    public void createInvoiceProposals(PSATmpProjProposalTrans _tmpProjProposalTrans)
    {
        int i;
        ProjProposalJour proposalJour;
        ProjTable projTable;

        this.progressInit("@SYS54552", 0);
        while select _tmpProjProposalTrans
        {
            if (i == 0)
            {
                this.parmDefaultDimension(_tmpProjProposalTrans.DefaultDimension);
                this.setProjProposalJour(_tmpProjProposalTrans.ProjInvoiceProjId, _tmpProjProposalTrans.ProjId,
                _tmpProjProposalTrans.FundingSourceRefId, _tmpProjProposalTrans.CurrencyCode, 
                _tmpProjProposalTrans.TaxInformation_IN, _tmpProjProposalTrans.FixedExchRate);
                i++;
            }

            this.setProjProposalJourPost(_tmpProjProposalTrans);

            select firstonly RecId from projTable
                where projTable.ProjId == _tmpProjProposalTrans.ProjId &&
                        projTable.ProjInvoiceProjId == _tmpProjProposalTrans.ProjInvoiceProjId
                exists join proposalJour
                    where proposalJour.ProjInvoiceProjId == projTable.ProjInvoiceProjId &&
                            proposalJour.ProposalId == projProposalJour.ProposalId;

            if (projTable.RecId)
            {
                this.doEmpl(_tmpProjProposalTrans.ProjInvoiceProjId, _tmpProjProposalTrans.RefRecId);
            }

            if (!this.parmSkipRecalculateProposalTotals())
            {
                this.updateInvoice();

                // When an invoice proposal is generated, the system will
                // automatically create retainage withholding records and/or retainage billing records at the project level.
                this.calcRetention();
            }
        }
    }

    public static ProjProposalId createDataInTmp(ProjFundingSourceRefId _fundingSource, JournalId _journalId)
    {
        ProjInvoiceProposalCreateLinesParams proposalCreateLinesParams = ProjInvoiceProposalCreateLinesParams::construct();
        ProjInvoiceProposalCreateLines proposalCreateLines;
        ProjInvoiceProposalInsertLines projInvoiceProposalInsertLines;
        ProjEmplTransSale ProjEmplTransSale;
        PSATmpProjProposalTrans tmpProjProposalTrans;
        ProjEmplTrans ProjEmplTrans;
        ProjJournalTrans projJournalTrans;
        TransDate invoiceDate = DateTimeUtil::getToday(DateTimeUtil::getUserPreferredTimeZone());
        ProjProposalId proposalId;

        proposalCreateLinesParams.parmInvoiceDate(invoiceDate);
        proposalCreateLinesParams.parmInvoiceTypeSelection(ProjInvoiceTypeSelection::Both);

        proposalCreateLines = ProjInvoiceProposalCreateLines::newStandard(proposalCreateLinesParams.pack());
        proposalCreateLines.parmProposalCreateLinesParams().parmInvoiceDate(invoiceDate);

        projInvoiceProposalInsertLines = new ProjInvoiceProposalInsertLines(proposalCreateLines, false);

        select firstonly Voucher from ProjJournalTrans
            where ProjJournalTrans.JournalId == _journalId;

        while select ProjEmplTrans
            where ProjEmplTrans.VoucherJournal == ProjJournalTrans.Voucher
        {
            select firstonly ProjEmplTransSale
                where ProjEmplTransSale.TransId == ProjEmplTrans.TransId
                   && ProjEmplTransSale.FundingSource == _fundingSource;

            tmpProjProposalTrans.initFromProjEmplTrans(ProjEmplTrans);
            tmpProjProposalTrans.FundingSourceRefId = _fundingSource;
            tmpProjProposalTrans.LineAmount = ProjEmplTransSale.LineAmount * -1;
            tmpProjProposalTrans.SalesPrice = ProjEmplTransSale.SalesPrice;
            tmpProjProposalTrans.Selected = true;
            tmpProjProposalTrans.RefRecId = ProjEmplTransSale.RecId;
            tmpProjProposalTrans.RefTableId = ProjEmplTransSale.TableId;
            tmpProjProposalTrans.IndirectAmount = ProjEmplTransSale.PSAIndirectInvoice;
            tmpProjProposalTrans.insert();
        }

        new TestCreateInvoiceProposal(proposalCreateLines, false).createInvoiceProposals(tmpProjProposalTrans);

        select firstonly ProjEmplTrans
            where ProjEmplTrans.VoucherJournal == ProjJournalTrans.Voucher
        join ProjEmplTransSale
            where ProjEmplTransSale.TransId == ProjEmplTrans.TransId
               && ProjEmplTransSale.FundingSource == _fundingSource;

        proposalId = ProjTrans::newProjEmplTransSale(ProjEmplTrans, ProjEmplTransSale).proposalId();

        return proposalId;
    }
}
Main Method to Call the Above Code

Below is the main method to call the above code from a runnable class also above methods need to add in same class

public class TestCreateHourJournalPostAndCreateInvProposalAndPostInvoice
{
    public static void main(Args _args)
    {
        JournalId journalId;
        ProjProposalId 	proposalId;
        InvoiceId 	invoiceId;
        
        TestCreateHourJournalPostAndCreateInvProposalAndPostInvoice objCreateHourJourAndCreateAndPostInvoice = 
new TestCreateHourJournalPostAndCreateInvProposalAndPostInvoice();

        journalId = objCreateHourJourAndCreateAndPostInvoice.createJournal();
        objCreateHourJourAndCreateAndPostInvoice.postJournal(journalId);
        proposalId = objCreateHourJourAndCreateAndPostInvoice.invoiceProposalCreation(journalId);
        invoiceId = objCreateHourJourAndCreateAndPostInvoice.postInvoiceProposal(proposalId);
        info(strfmt("invoice %1 posted",invoiceId);
    }
}


This was originally posted here.

Comments